标签:-------- RECTNG TA AREA 2D ANSYS SAVE TB apdl
文章目录
前言
把螺线管制动器作为2D轴对称模型进行分析,计算衔铁部分(螺线管制动器的运动部分)的受力情况和线圈电感。螺线管制动器如下图所示。相关参数如下表所示。
参数表
命令
/filname,emage_2D,1
/title,2D solenoid,actuator static analysis
keyw,magnod,1 !指定磁场分析
/prep7
et,1,plane13
keyopt,1,3,1 !指定分析类型为轴对称
MP,MURX,1,1 !指定空气的材料特性
MP,MURX,2,1000 !指定铁芯的材料特性
MP,MURX,3,1 !指定线圈的材料特性
MP,MURX,4,2000 !指定衔铁的材料特性
N=650 !线圈匝数
I=1.0 !每圈电流
!模型尺寸参数(cm)
TA=0.75
TB=0.75
TC=0.50
TD=0.75
WC=1
HC=2
GAP=0.25
SPACE=0.25
WS=WC+2*SPACE
HS=HC+0.75
W=TA+WS+TC
HB=TB+HS
H=HB+GAP+TD
ACOLL=WC*HC !线圈横截面积
JDENS=N*I/ACOLL !电流密度
/PNUM,AREA,1
RECTNG,0,W,0,TB
RECTNG,0,W,TB,HB
RECTNG,TA,TA+WS,0,H
RECTNG,TA+SPACE,TA+SPACE+WC,TB+SPACE,TB+SPACE+HC
AOVLAP,ALL !面搭接
SAVE
RECTNG,0,W,0,HB+GAP
RECTNG,0,W,0,H
AOVLAP,ALL
NUMCMP,AREA !压缩编号
APLOT
SAVE,EMAGE_2D_GEOM.DB
SAVE
ASEL,S,AREA,,2
AATT,3,1,1,0 !给线圈赋予材料属性
ASEL,S,AREA,,1
ASEL,A,AREA,,12,13
AATT,4,1,1,0 !给衔铁赋予材料属性
ASEL,S,AREA,,3,5
ASEL,A,AREA,,7,8
AATT,2,1,1,0 !给铁芯域赋予材料属性
/PNUM,MAT,1
ALLSEL,ALL
APLOT
SMARTSIZE,4 !设置智能划分网格等级
AMESH,ALL
SAVE,EMAGE_2D_MESH.DB
SAVE
ESEL,S,MAT,,4
CM,ARM,ELEM
ALLSEL,ALL
ARSCAL,ALL,,,0.01,0.01,1,,0,1 !改变单位制为MSK单位(m)
FINISH
!==========================
/SOLU
ESEL,S,MAT,,3 !选择线圈上的单元
BFE,ALL,JS,1,,,JDENS/(0.01**2) !施加电流密度载荷
ALLSEL,ALL
NSEL,EXT !选择外层节点
D,ALL,AZ,0 !施加磁力线平行边界条件
MAGSOLV,0,3,0.001,,25 !求解并计算
SAVE,EMAGE_2D_RESU.DB
SAVE
FINISH
!=======================
/POST1
PLF2D,27,0,10,1 !显示磁力线图
PLVECT,B,,,,VECT,ELEM,ON,0 !显示磁通密度矢量
/GRAPHICS,POWER
AVRES,2
PLNSOL,B,SUM !显示磁通密度等值云图
FINISH
结果
磁通密度等值云图
节点磁流密度扩展:执行菜单栏中的Utility Menu > PlotCtrls > Style > Symmetry Expansion > 2D Axi-Symmetric命令,弹出一个“ 2D Ax1-Syinmec ExpatniStOw N I阳S,心n Itexpansion”,单击“OK”按钮。如下图所示:
标签:--------,RECTNG,TA,AREA,2D,ANSYS,SAVE,TB,apdl 来源: https://blog.csdn.net/qq_45842873/article/details/110821930
本站声明: 1. iCode9 技术分享网(下文简称本站)提供的所有内容,仅供技术学习、探讨和分享; 2. 关于本站的所有留言、评论、转载及引用,纯属内容发起人的个人观点,与本站观点和立场无关; 3. 关于本站的所有言论和文字,纯属内容发起人的个人观点,与本站观点和立场无关; 4. 本站文章均是网友提供,不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属;如您发现该文章侵犯了您的权益,可联系我们第一时间进行删除; 5. 本站为非盈利性的个人网站,所有内容不会用来进行牟利,也不会利用任何形式的广告来间接获益,纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。