d编译时闭包

2021-12-08 19:30:02 阅读：155 来源： 互联网

//https://forum.dlang.org/post/sopoeb$1098$1@digitalmars.com
import std.stdio, std.traits, core.lifetime;

struct CtDelegate(R,T...){
    void* ctx;
    R function(T,void*) fp;
    R delegate(T) get(){
        R delegate(T) dg;
        dg.ptr=ctx;
        dg.funcptr=cast(typeof(dg.funcptr))fp;
        return dg;
    }
    alias get this;
    this(void* ctx,R function(T,void*) fp){ this.ctx=ctx; this.fp=fp; }
    R opCall(T args){ return fp(args,ctx); }
}

auto makeCtDelegate(alias f,C)(C ctx){
    static struct Ctx{ C ctx; }
    return CtDelegate!(ReturnType!(typeof(f)),ParameterTypeTuple!f[0..$-1])(new Ctx(forward!ctx),
          (ParameterTypeTuple!f[0..$-1] args,void* ctx){ auto r=cast(Ctx*)ctx; return f(r.ctx,forward!args); });
}

struct A{
    CtDelegate!void[] dg;
}

auto createDelegate(string s){
    return makeCtDelegate!((string s){ s.writeln; })(s);
}

A create(){
    A a;
    a.dg ~= createDelegate("hello");
    a.dg ~= createDelegate("buy");
    return a;
}


void main(){
    static a = create();
    foreach(dg; a.dg)dg();
}
//另一版本:
interface ICallable
{
    void opCall() const;
}

auto makeDelegate(alias fun, Args...)(auto ref Args args)
{
    return new class(args) ICallable
    {
        Args m_args;
        this(Args p_args) { m_args = p_args; }
        void opCall() const { fun(m_args); }
    };
}

alias Action = void delegate();

Action createDelegate(string s)
{
    import std.stdio;
    return &makeDelegate!((string str) => writeln(str))(s).opCall;
}

struct A
{
    Action[] dg;
}

A create()
{
    A a;
    a.dg ~= createDelegate("hello");
    a.dg ~= createDelegate("buy");
    return a;
}

void main()
{
    enum a = create();
    foreach(dg; a.dg)dg();
}

标签：fp,return,dg,void,args,ctx,时闭,编译
来源： https://blog.csdn.net/fqbqrr/article/details/121798967

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。

ICode9

d编译时闭包