进入32位保护模式之路

2021-06-14 09:31:20 阅读：240 来源： 互联网

标签：保护模式 32 EQU AL MOV CALL 进入 ESI ECX

; haribote-os boot asm
; TAB=4

BOTPAK	EQU		0x00280000		
DSKCAC	EQU		0x00100000		 
DSKCAC0	EQU		0x00008000		 

; BOOT_INFO
CYLS	EQU		0x0ff0			; 设定启动区
LEDS	EQU		0x0ff1
VMODE	EQU		0x0ff2			; 关于颜色数目的信息  颜色的位数
SCRNX	EQU		0x0ff4			; 分辨率的X 
SCRNY	EQU		0x0ff6			; 分辨率的Y
VRAM	EQU		0x0ff8			; 图像缓冲区的开始地址

		ORG		0xc200			; 程序装载地址

		MOV		AL,0x13			; VGA显卡   320*200*8位色
		MOV		AH,0x00
		INT		0x10
		MOV		BYTE [VMODE],8	; 记录画面模式
		MOV		WORD [SCRNX],320
		MOV		WORD [SCRNY],200
		MOV		DWORD [VRAM],0x000a0000

; 用BIOS取得键盘上 各种LED指示灯的状态

		MOV		AH,0x02
		INT		0x16 			; keyboard BIOS
		MOV		[LEDS],AL

; PIC关闭一切中断
;	AT兼容机的规格 如果要初始化PIC
;	必须在cli之前进行 否则有可能被挂起
;	随后进行PIC的初始化

		MOV		AL,0xff
		OUT		0x21,AL
		NOP						; 让CPU在此等待一下 
		OUT		0xa1,AL

		CLI						; 禁止CPU级别的中断

; CPU为了访问1M以上的内存，设定A20Gate
;A20Gate 是由键盘控制器来操控的

		CALL	waitkbdout
		MOV		AL,0xd1			
		;准备写OutPut端口 随后通过60h写入的数据，放置在OutPut Port
		OUT		0x64,AL
		CALL	waitkbdout
		MOV		AL,0xdf			; enable A20
		OUT		0x60,AL
		CALL	waitkbdout

; 切换到保护模式

[INSTRSET "i486p"]				; 想要使用486指令的叙述 

		LGDT	[GDTR0]			; 设定临时的GDT
		MOV		EAX,CR0
		AND		EAX,0x7fffffff	; 设置PG位为1 禁止分页
		OR		EAX,0x00000001	; 设置PE位为1 保护模式
		MOV		CR0,EAX
		JMP		pipelineflush	;模式发生变化 重新解释指令
pipelineflush:
		MOV		AX,1*8			;  可读写的段 32bit
		MOV		DS,AX			;0x0008 相当于GDT+1
		MOV		ES,AX
		MOV		FS,AX
		MOV		GS,AX
		MOV		SS,AX

; bootpack的传送

		MOV		ESI,bootpack	; 传送源
		MOV		EDI,BOTPAK		; 传送目的
		MOV		ECX,512*1024/4
		CALL	memcpy

; 磁盘数据最后送回它本来的位置

; 首先从启动扇区开始

		MOV		ESI,0x7c00		; 传送源
		MOV		EDI,DSKCAC		; 传送目的
		MOV		ECX,512/4
		CALL	memcpy

; 所有剩下的

		MOV		ESI,DSKCAC0+512	; 传送源
		MOV		EDI,DSKCAC+512	; 传送目的
		MOV		ECX,0
		MOV		CL,BYTE [CYLS]
		IMUL	ECX,512*18*2/4	; 从柱面数变化成字节数
		SUB		ECX,512/4		; 减去IPL的
		CALL	memcpy

; asmhead的任务全部完成
;	下面由bootpack来完成

; bootpack的启动

		MOV		EBX,BOTPAK
		MOV		ECX,[EBX+16]
		ADD		ECX,3			; ECX += 3;
		SHR		ECX,2			; ECX /= 4;
		JZ		skip			; 没有要转送的东西时
		MOV		ESI,[EBX+20]	; 传送源
		ADD		ESI,EBX
		MOV		EDI,[EBX+12]	; 传送目的
		CALL	memcpy
skip:
		MOV		ESP,[EBX+12]	;栈初始化
		JMP		DWORD 2*8:0x0000001b

waitkbdout:
		IN		 AL,0x64
		AND		 AL,0x02
		JNZ		waitkbdout		; 空读 为了清空接受缓冲区中的垃圾
		RET

memcpy:
		MOV		EAX,[ESI]
		ADD		ESI,4
		MOV		[EDI],EAX
		ADD		EDI,4
		SUB		ECX,1
		JNZ		memcpy			; 
		RET
; 

		ALIGNB	16
GDT0:	;特殊的GDT 不能在这里设置段
		RESB	8				; NULL SELECTOR
		DW		0xffff,0x0000,0x9200,0x00cf	; 可以读写的段 32bits
		DW		0xffff,0x0000,0x9a28,0x0047	; 可以执行的段 32bits

		DW		0
GDTR0:
		DW		8*3-1
		DD		GDT0

		ALIGNB	16
bootpack:

标签：保护模式,32,EQU,AL,MOV,CALL,进入,ESI,ECX
来源： https://blog.csdn.net/ZZHinclude/article/details/117897958

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。

ICode9

进入32位保护模式之路